Back to main page | Email me at: Gene!

This program is designed to be used in teaching children the four operations of arithmetic. Problems are displayed with one number to the left of the decimal and the other number to the right. Example: 8 and 2 are displayed as 8.02. The user then decides which operation to perform, keys in his/her answer and reinitiates the program. Although all numbers in the problems are positive, some results of the subtractions will be negative.

User Instructions:
1) Key in program
2) Store seed (0 < seed < 1) STO 1
3) Store maximum number to be used: STO 2
4) Press GSB 0 - problem is displayed in the form of XX.YY

5) Choose an operation and input your answer:
For addition, input your answer and press GSB 1.
For subtraction, input your answer and press GSB 2.
For multiplication, input your answer and press GSB 3.
For division, input your answer and press GSB 4.

6) If you are correct, the next problem is displayed.
7) If you are incorrect, the problem will be shown again but will have a negative sign in the Display.
8) If you get an error (division by zero), press the CLX key and go to step 4.

Line      Instruction
01         LBL 0
02         FIX 2
03         GSB 9
04         STO 4
05         GSB 9
06         STO 3
07         RCL 4
08         EEX
09         2
10         /
11         +
12         STO 5
13         R/S
14         LBL 9
15         RCL 1
16         PI
17         X^2
18         *
19         FRC
20         STO 1
21         RCL 2
22         1
23         +
24         *
25         INT
26         RTN
27         LBL 1
28         RCL 3
29         RCL 4
30         +
31         GTO 8
32         LBL 2
33         RCL 3
34         RCL 4
35         -
36         GTO 8
37         LBL 3
38         RCL 3
39         RCL 4
40         *
41         GTO 8
42         LBL 4
43         RCL 3
44         RCL 4
45         /
46         LBL 8
47         X = Y?
48         GTO 0
49         RCL 5
50         CHS
51         R/S