The Game: You are presented with the numbers 1-9 in a list. A roll of two dice occurs and you attempt to choose a combination of numbers out of the 1-9 list that add up to the total of the two dice. If you can do so, the numbers chosen disappear from the list and another pair of dice are rolled. This continues until you either exactly remove all the 1-9 numbers or you cannot put together a combination of numbers that total your dice roll.

Pretty simple? So it sounds. It's actually very hard to do. I've played well over 1000 rounds of this game and my average percent of the time that I've won is around 16%.

Other rules: 1) You may not choose a number from the list more than once. (If you get a 1 and 3 on the two dice that are rolled, you may not choose 2 and 2 as the numbers to be removed from the list). 2) If the two dice you roll are the same, you are given a "doubles" chip. This doubles chip is used as insurance should you get a roll that you cannot find a correct combination in the list. This will be clearer from the game example below.

Once the game ends, you are shown your cumulative game score and the game starts over automatically (it assumes that you want to keep playing. ;-) ).

Start by XEQ HR.

SEED?                   Let's use a seed of 0.611940299 

0.611940299 ENTER

1,1:1:123456789        You've rolled two 1's. Your bonus chip is 
                       indicated by the "1" between the two colons.

2 R/S                  2 is equal to the two 1's you rolled and will be
                       removed from the list. 

5,5:2:1 3456789        You've rolled two 5's. Another bonus chip
                       (aren't you lucky?). Notice the two from last 
                       time has disappeared. Only 8 more numbers to go!

64 R/S                 6 and 4 equal 10 (the sum of the two 5's just 
                       rolled). You've now got 2 bonus attempts in case 
                       you can't find a proper combination.

2,1:2:1 3 5 789        You've rolled a 2 and 1. Notice again the 6 and 
                       4 have disappeared. Let's try something wrong.

9  R/S                 9 is not a proper entry for rolling a 2 and a 1. 
                       It should return the display with no changes.

2,1:2:1 3 5 789        It does. Let's choose 3 this time.

3  R/S 

5,6:2:1   5 789        We've rolled a 5 and 6. No combination exists 
                       that will work. To "pass" on this roll and 
                       indicate we have no move, enter a zero (or 
                       decimal point).

 0  R/S

4,2:1:1   5 789        Notice the 2 bonus chips have dropped to 1. We 
                       used one last time. Enter a 1 and 5 to use up 
                       the 6 (4 and 2) just rolled.

 15  R/S 

2,6:1:      789        A 2 and 6. Let's use up the 8.

8  R/S 

2,2:2:      7 9        Doubles, but this does us no good.

0  R/S

3,4:1:      7 9        Almost there! Let's use up the 7.

7  R/S 

3,4:1:        9        Another 7.  We have to use up our last bonus 
                       insurance chip!

0  R/S

3,6:          9        Great! We've won!

9  R/S

1/1 100.00%            Our record so far is pretty good!

1,3:   123456789       The next game has started....

A few lines below might need some explanation. Line 18 is append comma. Line 20 is append colon. Anywhere X NE 0? or X NE Y? is found they are X not equal to zero or X not equal to Y. Line 31 is append colon. Lines 33, 38 and 109 are append space (1 space only). Line 107 is append slash (the divide symbol). RDN is roll down, and RUP is roll up. Everything else should be self-explanatory!

Line      Instruction
01         LBL "HR"
02         CF 29
03         FIX 0
04         "SEED?"
05         PROMPT
06         STO 00
07         LBL 01
08         9
09         LBL 02
10         STO IND X
11         DSE X
12         GTO 02
13         LBL 03
14         XEQ 04
15         CLA
16         ARCL X
17         XEQ 04
18         ->","
19         ARCL X
20         ->":"
21         X NE Y?
22         GTO 12
23         ISG 13
24         LBL 12
25         +
26         STO 12
27         RCL 13
28         X NE 0?
29         ARCL X
30         X NE 0?
31         ->":"
32         X=0?
33         ->" "
34         1.009
35         LBL 05
36         RCL IND X
37         X=0?
38         ->" "
39         X NE 0?
40         ARCL X
41         RDN
42         ISG X
43         GTO 05
44         LBL 06
45         PROMPT
46         FC?C 22
47         GTO 06
48         X=0?
49         GTO 07
50         ENTER
51         ENTER
52         0
53         X<>Y
54         ENTER
55         LOG
56         INT
57         10^X
58         /
59         LBL 08
60         INT
61         RCL IND X
62         X=0?
63         GTO 06
64         RDN
65         LASTX
66         RDN
67         +
68         RUP
69         FRC
70         10
71         *
72         X NE 0?
73         GTO 08
74         RDN
75         RCL 12
76         X NE Y?
77         GTO 06
78         RDN
79         RDN
80         LOG
81         INT
82         10^X
83         /
84         LBL 09
85         0
86         STO IND Y
87         RDN
88         FRC
89         10
90         *
91         X NE 0?
92         GTO 09
93         9
94         LBL 10
95         RCL IND X
96         X NE 0?
97         GTO 03
98         RDN
99         DSE X
100        GTO 10
101        ISG 14
102        LBL 11
103        1
104        ST+ 15
105        CLA
106        ARCL 14
107        ->"/"
108        ARCL 15
109        ->" "
110        RCL 14
111        RCL 15
112        /
113        100
114        *
115        FIX 2
116        ARCL X
117        AVIEW
118        FIX 0
119        CLX
120        STO 13
121        GTO 01
122        LBL 07
123        RCL 13
124        X=0?
125        GTO 11
126        1
127        ST- 13
128        GTO 03
129        LBL 04
130        RCL 00
131        997
132        *
133        FRC
134        STO 00
135        6
136        *
137        1
138        +
139        INT
140        END